The Strongest Possible Lewisian Triviality Result

Branden Fitelson
April 23, 2015

This notebook makes extensive use of the functions provided in my PrSAT package, which can be downloaded here:

	http://fitelson.org/PrSAT/

First, we need to load in the PrSAT package.

<<PrSAT`

Here is a set of functions which compute all (191) instances of The Resilient Equation.

states={ℭ∧P∧Q,ℭ∧P∧¬Q,ℭ∧¬P∧Q,ℭ∧¬P∧¬Q,¬ℭ∧P∧Q,¬ℭ∧P∧¬Q,¬ℭ∧¬P∧Q,¬ℭ∧¬P∧¬Q};
props=Or@@#&/@Subsets[states];
test[p_]:=Not[BooleanMinimize[p&&P]===False]&&!TautologyQ[Implies[p&&P,(¬Q&&ℭ)||(Q&&¬ℭ)]];
PconProps=Drop[BooleanMinimize/@Select[props,test[#]&],-1];
RESILIENT=Table[Pr[ℭ|PconProps[[i]]]==Pr[Q|BooleanMinimize[P&&PconProps[[i]]]],{i,1,Length[PconProps]}];

RESILIENT//Length

Here PrSAT’s internal stochastic truth-table representation of the set of probability functions over the states induced by {P,Q,ℭ}, where ℭ is (extra-systematically interpreted as) the indicative conditional P ⟶ Q.

({{P, Q, ℭ, Pr[•]}, {T, T, T, (Subscript[𝕒, 8])}, {T, T, F, (Subscript[𝕒, 5])}, {T, F, T, (Subscript[𝕒, 6])}, {T, F, F, (Subscript[𝕒, 2])}, {F, T, T, (Subscript[𝕒, 7])}, {F, T, F, (Subscript[𝕒, 3])}, {F, F, T, (Subscript[𝕒, 4])}, {F, F, F, (Subscript[𝕒, 1])}})

The PrReduce function gives necessary and sufficient conditions for the satisfaction of a probabilistic constraint.  When we run it on the (conjunction of the) full set RESILIENT of instances of The Resilient Equation, we see that probability masses (Subscript[𝕒, 8]) and (Subscript[𝕒, 2]) are the only ones that are non-zero.

Triviality=PrReduce[And@@RESILIENT]

In other words, we’re down to the following single-parameter stochastic truth-table (as reported in the paper).

({{P, Q, ℭ, state, Pr[•]}, {T, T, T, (Subscript[𝕒, 8]), 1-a}, {T, T, F, (Subscript[𝕒, 5]), 0}, {T, F, T, (Subscript[𝕒, 6]), 0}, {T, F, F, (Subscript[𝕒, 2]), 0<a<1}, {F, T, T, (Subscript[𝕒, 7]), 0}, {F, T, F, (Subscript[𝕒, 3]), 0}, {F, F, T, (Subscript[𝕒, 4]), 0}, {F, F, F, (Subscript[𝕒, 1]), 0}})

The following computations establish the two directions of Triviality (assuming Pr(P & Q) > 0 and Pr(P &~Q) > 0).

p_≡q_:=Implies[p,q]&&Implies[q,p];

First, the left-to-right direction.

PrSAT[{Pr[P∧(Q≡ℭ)]<1,RESILIENT},BypassSearch->True]

Then, the right-to-left direction.

PrSAT[{Pr[P∧(Q≡ℭ)]==1,Or@@(Not/@RESILIENT)},BypassSearch->True]

The following calculation shows that we only need our three instances of The Resilient Equation to deduce Triviality.

PrReduce[And@@{
(* Lewis's Instance + Milne's Instance of The Resilient Equation *)
Pr[ℭ|¬Q]==0, (* let X = ¬Q *)
Pr[ℭ| ¬P∨Q] == Pr[Q| P∧( ¬P∨Q)],(* let X = ¬P∨Q *)

(* The Equation *)
Pr[ℭ]==Pr[Q|P]
}]===Triviality

Lewis’s result is weaker than ours — it does not imply Pr(P) = 1.

PrSAT[{
(* Lewis's Two Instances of The Resilient Equation *)
Pr[ℭ|¬Q]==0, (* let X = ¬Q *)
Pr[ℭ| Q] ==1,(* let X = Q *)

(* Failure of Pr[P]=1 *)
Pr[P]<1
}]

Milne’s Result is weaker than ours — it does not imply either Pr(P) = 1 or Pr(Q) = Pr(P ⟶ Q).

PrSAT[{
(* Milne's instance of The Resilient Equation *)
Pr[ℭ| ¬P∨Q] == Pr[Q| P∧( ¬P∨Q)], (* let X = ¬P∨Q *)

(* Both Pr(P) < 1 and Pr[Q] ≠ Pr[P ⟶ Q] *)
Pr[P]<1,Pr[Q]≠Pr[ℭ]
},BypassSearch->True]

As it happens, there are pairs of constraints from RESILIENT that entails Triviality.  [This pair was discovered by a long and complicated search process that I will not reproduce here.]  Here is one such pair:

PrReduce[Pr[ℭ|(P&&Q)||(¬P&&¬ℭ)]==Pr[Q|P&&Q]&&Pr[ℭ|(P&&¬Q)||(¬P&&ℭ)]==Pr[Q|P&&¬Q]]

That is, the first instance of the pair takes: X := ((P∧Q) ∨ (¬P∧¬ℭ)).  And, the second instance of the pair takes X := (P∧¬Q) ∨ (¬P∧ℭ).

FullSimplify[P∧((P∧Q)∨(¬P∧¬ℭ))]

FullSimplify[P∧((P∧¬Q)∨(¬P∧ℭ))]

This is “simpler” in one sense (i.e., as it involves 2 constraints rather than 3), but it is more complex in terms of (a) the propositions involved and (b) how this version of our triviality argument relates to the existing arguments of Lewis and Milne.