Probabilistic Measures of Causal Strength

Branden Fitelson (UC–Berkeley)
Christopher Hitchcock (Caltech)

This is a companion Mathematica notebook for our paper "Probabilistic Measures of Causal Strength", which can be downloaded from http://fitelson.org/pmcs.pdf.

Requires the PrSAT package, which can be downloaded from http://fitelson.org/PrSAT/.

<<PrSAT`

Defining the measures (Table 1)

In this section we give definitions of our measures of causal strength (CS) and preventative strength (PS), as described in Table 1 of the paper.  As discussed in the beginning of the paper, we define PS(E,C) = -CS(¬E,C) for each of our CS-measures, and we introduce two rescalings for each of the CS-measures that are not already defined on [–1,1].

Eells

CS𝕖[e_,c_]:=Pr[e|c]-Pr[e|¬c];
CS𝕖[e_,c1_,c2_]:=Pr[e|c1∧c2]-Pr[e|¬c1∧c2];

PS𝕖[e_,c_]:=-CS𝕖[¬e,c];
PS𝕖[e_,c1_,c2_]:=-CS𝕖[¬e,c1,c2];

Suppes

CS𝕤[e_,c_]:=Pr[e|c]-Pr[e];
CS𝕤[e_,c1_,c2_]:=Pr[e|c1∧c2]-Pr[e|c2];

PS𝕤[e_,c_]:=-CS𝕤[¬e,c];
PS𝕤[e_,c1_,c2_]:=-CS𝕤[¬e,c1,c2];

Galton

CS𝕘[e_,c_]:=4 Pr[c] Pr[¬c](Pr[e|c]-Pr[e|¬c]);
CS𝕘[e_,c1_,c2_]:=4 Pr[c1|c2] Pr[¬c1|c2](Pr[e|c1∧c2]-Pr[e|¬c1∧c2]);

PS𝕘[e_,c_]:=-CS𝕘[¬e,c];
PS𝕘[e_,c1_,c2_]:=-CS𝕘[¬e,c1,c2];

Cheng

CS𝕔[e_,c_]:=((Pr[e|c]-Pr[e|¬c])/(Pr[¬e|¬c]));
CS𝕔[e_,c1_,c2_]:=((Pr[e|c1∧c2]-Pr[e|¬c1∧c2])/(Pr[¬e|¬c1∧c2]));

PS𝕔[e_,c_]:=-CS𝕔[¬e,c];
PS𝕔[e_,c1_,c2_]:=-CS𝕔[¬e,c1,c2];

Lewis Ratio

CS𝕝𝕣[e_,c_]:=Pr[e|c]/Pr[e|¬c];
CS𝕝𝕣[e_,c1_,c2_]:=Pr[e|c1∧c2]/Pr[e|¬c1∧c2];

First rescaling of Lewis Ratio

CS𝕝𝕣1[e_,c_]:=((Pr[e|c]-Pr[e|¬c])/(Pr[e|c]+Pr[e|¬c]));
CS𝕝𝕣1[e_,c1_,c2_]:=((Pr[e|c1∧c2]-Pr[e|¬c1∧c2])/(Pr[e|c1∧c2]+Pr[e|¬c1∧c2]));

PS𝕝𝕣1[e_,c_]:=-CS𝕝𝕣1[¬e,c];
PS𝕝𝕣1[e_,c1_,c2_]:=-CS𝕝𝕣1[¬e,c1,c2];

Second rescaling of Lewis Ratio

CS𝕝𝕣2[e_,c_]:=1-(1/CS𝕝𝕣[e,c]);
CS𝕝𝕣2[e_,c1_,c2_]:=1-(1/CS𝕝𝕣[e,c1,c2]);

PS𝕝𝕣2[e_,c_]:=-CS𝕝𝕣2[¬e,c];
PS𝕝𝕣2[e_,c1_,c2_]:=-CS𝕝𝕣2[¬e,c1,c2];

Good

CS𝕚𝕛[e_,c_]:=((Pr[¬e|¬c])/(Pr[¬e|c]));
CS𝕚𝕛[e_,c1_,c2_]:=((Pr[¬e|¬c1∧c2])/(Pr[¬e|c1∧c2]));

First rescaling of Good

CS𝕚𝕛1[e_,c_]:=((Pr[¬e|¬c]-Pr[¬e|c])/(Pr[¬e|¬c]+Pr[¬e|c]));
CS𝕚𝕛1[e_,c1_,c2_]:=((Pr[¬e|¬c1∧c2]-Pr[¬e|c1∧c2])/(Pr[¬e|¬c1∧c2]+Pr[¬e|c1∧c2]));

PS𝕚𝕛1[e_,c_]:=-CS𝕚𝕛1[¬e,c];
PS𝕚𝕛1[e_,c1_,c2_]:=-CS𝕚𝕛1[¬e,c1,c2];

Second rescaling of Good

CS𝕚𝕛2[e_,c_]:=1-(1/CS𝕚𝕛[e,c]);
CS𝕚𝕛2[e_,c1_,c2_]:=1-(1/CS𝕚𝕛[e,c1,c2]);

PS𝕚𝕛2[e_,c_]:=-CS𝕚𝕛2[¬e,c];
PS𝕚𝕛2[e_,c1_,c2_]:=-CS𝕚𝕛2[¬e,c1,c2];

Scale Verification

In this section, we verify that all the (possibly rescaled) measures we'll examine below, are on a [-1,1] scale.  We do this using the function PrRange (now part of the PrSAT package) which calculates the range of a probabilistic expression (first argument) subject to probabilistic constraints (second argument):

Eells

PrRange[CS𝕖[𝔼,ℂ],Pr[𝔼|ℂ]≥Pr[𝔼]]

PrRange[PS𝕖[𝔼,ℂ],Pr[𝔼|ℂ]≤Pr[𝔼]]

Suppes

PrRange[CS𝕤[𝔼,ℂ],Pr[𝔼|ℂ]≥Pr[𝔼]]

PrRange[PS𝕤[𝔼,ℂ],Pr[𝔼|ℂ]≤Pr[𝔼]]

Galton

PrRange[CS𝕘[𝔼,ℂ],Pr[𝔼|ℂ]≥Pr[𝔼]]

PrRange[CS𝕘[𝔼,ℂ],Pr[𝔼|ℂ]≤Pr[𝔼]]

Cheng

PrRange[CS𝕔[𝔼,ℂ],Pr[𝔼|ℂ]≥Pr[𝔼]]

PrRange[PS𝕔[𝔼,ℂ],Pr[𝔼|ℂ]≤Pr[𝔼]]

Lewis Ratio (two rescaled versions)

PrRange[CS𝕝𝕣1[𝔼,ℂ],Pr[𝔼|ℂ]≥Pr[𝔼]]

PrRange[PS𝕝𝕣1[𝔼,ℂ],Pr[𝔼|ℂ]≤Pr[𝔼]]

PrRange[CS𝕝𝕣2[𝔼,ℂ],Pr[𝔼|ℂ]≥Pr[𝔼]]

PrRange[PS𝕝𝕣2[𝔼,ℂ],Pr[𝔼|ℂ]≤Pr[𝔼]]

Good (two rescaled versions)

PrRange[CS𝕚𝕛1[𝔼,ℂ],Pr[𝔼|ℂ]≥Pr[𝔼]]

PrRange[PS𝕚𝕛1[𝔼,ℂ],Pr[𝔼|ℂ]≤Pr[𝔼]]

PrRange[CS𝕚𝕛2[𝔼,ℂ],Pr[𝔼|ℂ]≥Pr[𝔼]]

PrRange[PS𝕚𝕛2[𝔼,ℂ],Pr[𝔼|ℂ]≤Pr[𝔼]]

Inter-Definability Verification (Table 3)

Here, we verify the inter-definability relations stated in Table 3 of the paper, using the function PrReduce from the PrSAT package:

Suppes

PrReduce[{CS𝕤[𝔼,ℂ]==Pr[¬ℂ]CS𝕖[𝔼,ℂ]}]

Galton

PrReduce[{CS𝕘[𝔼,ℂ]==4 Pr[ℂ]Pr[¬ℂ]CS𝕖[𝔼,ℂ]==4 Pr[ℂ] CS𝕤[𝔼,ℂ]}]

Cheng

PrReduce[{CS𝕔[𝔼,ℂ]==((CS𝕖[𝔼,ℂ])/(Pr[¬𝔼|¬ℂ]))==((CS𝕤[𝔼,ℂ])/(Pr[¬𝔼∧¬ℂ]))==((CS𝕘[𝔼,ℂ])/(4Pr[ℂ] Pr[¬𝔼∧¬ℂ]))}]

Lewis Ratio

PrReduce[{CS𝕝𝕣1[𝔼,ℂ]==((CS𝕝𝕣[𝔼,ℂ]-1)/(CS𝕝𝕣[𝔼,ℂ]+1))==((CS𝕖[𝔼,ℂ])/(Pr[𝔼|ℂ]+Pr[𝔼|¬ℂ]))}]

PrReduce[{CS𝕝𝕣2[𝔼,ℂ]==1-(1/(CS𝕝𝕣[𝔼,ℂ]))==((CS𝕖[𝔼,ℂ])/(Pr[𝔼|ℂ]))==((CS𝕤[𝔼,ℂ])/(Pr[𝔼|ℂ]Pr[¬ℂ]))==CS𝕔[𝔼,ℂ]((Pr[¬𝔼|¬ℂ])/(Pr[𝔼|ℂ]))==((CS𝕘[𝔼,ℂ])/(4 Pr[𝔼∧ℂ]Pr[¬ℂ]))}]

Good

PrReduce[CS𝕚𝕛[𝔼,ℂ]==CS𝕝𝕣[¬𝔼,¬ℂ]]

PrReduce[{CS𝕚𝕛1[𝔼,ℂ]==((CS𝕚𝕛[𝔼,ℂ]-1)/(CS𝕚𝕛[𝔼,ℂ]+1))==CS𝕝𝕣1[¬𝔼,¬ℂ]==((CS𝕖[𝔼,ℂ])/(Pr[¬𝔼|ℂ]+Pr[¬𝔼|¬ℂ]))}]

PrReduce[{CS𝕚𝕛2[𝔼,ℂ]==1-(1/(CS𝕚𝕛[𝔼,ℂ]))==((CS𝕖[𝔼,ℂ])/(Pr[¬𝔼|¬ℂ]))==((CS𝕤[𝔼,ℂ])/(Pr[¬𝔼∧¬ℂ]))==((CS𝕘[𝔼,ℂ])/(4 Pr[¬𝔼∧¬ℂ]Pr[ℂ]))==CS𝕝𝕣2[¬𝔼,¬ℂ]}]

Ordinal Relationship Verification (Table 4)

In this section, we verify all the ordinal relationships between all pairs of measures — as recorded in Table 4 of the paper (going from the first row, downward by rows).  Here, we use PrSAT to search for models of the denials of the various ordinal relationships.  If a model is found, this shows that the ordinal relationship in question does not hold (and the model given is a concrete counter-model to the ordinal relationship in question).  If no model is found, then the ordinal relationship in question does hold.

Eells & Suppes

CS𝕖 and CS𝕤 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕖[𝔼1,ℂ1]≥CS𝕖[𝔼2,ℂ2],CS𝕤[𝔼1,ℂ1]<CS𝕤[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕖 and CS𝕤 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕖[𝔼,ℂ1]≥CS𝕖[𝔼,ℂ2],CS𝕤[𝔼,ℂ1]<CS𝕤[𝔼,ℂ2]},Probabilities->Regular]

CS𝕖 and CS𝕤 are ordinally equivalent in the class of cases with two effects and a single cause (they are II–E):

PrSAT[{CS𝕖[𝔼1,ℂ]≥CS𝕖[𝔼2,ℂ],CS𝕤[𝔼1,ℂ]<CS𝕤[𝔼2,ℂ]},Probabilities->Regular]

Eells & Galton

CS𝕖 and CS𝕘 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕖[𝔼1,ℂ1]≥CS𝕖[𝔼2,ℂ2],CS𝕘[𝔼1,ℂ1]<CS𝕘[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕖 and CS𝕘 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕖[𝔼,ℂ1]≥CS𝕖[𝔼,ℂ2],CS𝕘[𝔼,ℂ1]<CS𝕘[𝔼,ℂ2]},Probabilities->Regular]

CS𝕖 and CS𝕘 are ordinally equivalent in the class of cases with two effects and a single cause (they are II–E):

PrSAT[{CS𝕖[𝔼1,ℂ]≥CS𝕖[𝔼2,ℂ],CS𝕘[𝔼1,ℂ]<CS𝕘[𝔼2,ℂ]},Probabilities->Regular]

Eells & Cheng

CS𝕖 and CS𝕔 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕖[𝔼1,ℂ1]≥CS𝕖[𝔼2,ℂ2],CS𝕔[𝔼1,ℂ1]<CS𝕔[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕖 and CS𝕔 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕖[𝔼,ℂ1]≥CS𝕖[𝔼,ℂ2],CS𝕔[𝔼,ℂ1]<CS𝕔[𝔼,ℂ2]},Probabilities->Regular]

CS𝕖 and CS𝕔 are not ordinally equivalent in the class of cases with two effects and a single cause (they are not II–E):

PrSAT[{CS𝕖[𝔼1,ℂ]≥CS𝕖[𝔼2,ℂ],CS𝕔[𝔼1,ℂ]<CS𝕔[𝔼2,ℂ]},Probabilities->Regular]

Eells & Lewis Ratio

CS𝕖 and CS𝕝𝕣 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕖[𝔼1,ℂ1]≥CS𝕖[𝔼2,ℂ2],CS𝕝𝕣[𝔼1,ℂ1]<CS𝕝𝕣[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕖 and CS𝕝𝕣 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕖[𝔼,ℂ1]≥CS𝕖[𝔼,ℂ2],CS𝕝𝕣[𝔼,ℂ1]<CS𝕝𝕣[𝔼,ℂ2]},Probabilities->Regular]

CS𝕖 and CS𝕝𝕣 are not ordinally equivalent in the class of cases with two effects and a single cause (they are not II–E):

PrSAT[{CS𝕖[𝔼1,ℂ]≥CS𝕖[𝔼2,ℂ],CS𝕝𝕣[𝔼1,ℂ]<CS𝕝𝕣[𝔼2,ℂ]},Probabilities->Regular]

Eells & Good

CS𝕖 and CS𝕚𝕛 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕖[𝔼1,ℂ1]≥CS𝕖[𝔼2,ℂ2],CS𝕚𝕛[𝔼1,ℂ1]<CS𝕚𝕛[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕖 and CS𝕚𝕛 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕖[𝔼,ℂ1]≥CS𝕖[𝔼,ℂ2],CS𝕚𝕛[𝔼,ℂ1]<CS𝕚𝕛[𝔼,ℂ2]},Probabilities->Regular]

CS𝕖 and CS𝕚𝕛 are not ordinally equivalent in the class of cases with two effects and a single cause (they are not II–E):

PrSAT[{CS𝕖[𝔼1,ℂ]≥CS𝕖[𝔼2,ℂ],CS𝕚𝕛[𝔼1,ℂ]<CS𝕚𝕛[𝔼2,ℂ]},Probabilities->Regular]

Suppes & Galton

CS𝕤 and CS𝕘 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕤[𝔼1,ℂ1]≥CS𝕤[𝔼2,ℂ2],CS𝕘[𝔼1,ℂ1]<CS𝕘[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕤 and CS𝕘 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕤[𝔼,ℂ1]≥CS𝕤[𝔼,ℂ2],CS𝕘[𝔼,ℂ1]<CS𝕘[𝔼,ℂ2]},Probabilities->Regular]

CS𝕤 and CS𝕘 are ordinally equivalent in the class of cases with two effects and a single cause (they are II–E):

PrSAT[{CS𝕤[𝔼1,ℂ]≥CS𝕤[𝔼2,ℂ],CS𝕘[𝔼1,ℂ]<CS𝕘[𝔼2,ℂ]},Probabilities->Regular]

Suppes & Cheng

CS𝕤 and CS𝕔 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕤[𝔼1,ℂ1]≥CS𝕤[𝔼2,ℂ2],CS𝕔[𝔼1,ℂ1]<CS𝕔[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕤 and CS𝕔 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕤[𝔼,ℂ1]≥CS𝕤[𝔼,ℂ2],CS𝕔[𝔼,ℂ1]<CS𝕔[𝔼,ℂ2]},Probabilities->Regular]

CS𝕤 and CS𝕔 are not ordinally equivalent in the class of cases with two effects and a single cause (they are not II–E):

PrSAT[{CS𝕤[𝔼1,ℂ]≥CS𝕤[𝔼2,ℂ],CS𝕔[𝔼1,ℂ]<CS𝕔[𝔼2,ℂ]},Probabilities->Regular]

Suppes & Lewis Ratio

CS𝕤 and CS𝕝𝕣 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕤[𝔼1,ℂ1]≥CS𝕤[𝔼2,ℂ2],CS𝕝𝕣[𝔼1,ℂ1]<CS𝕝𝕣[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕤 and CS𝕝𝕣 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕤[𝔼,ℂ1]≥CS𝕤[𝔼,ℂ2],CS𝕝𝕣[𝔼,ℂ1]<CS𝕝𝕣[𝔼,ℂ2]},Probabilities->Regular]

CS𝕤 and CS𝕝𝕣 are not ordinally equivalent in the class of cases with two effects and a single cause (they are not II–E):

PrSAT[{CS𝕤[𝔼1,ℂ]≥CS𝕤[𝔼2,ℂ],CS𝕝𝕣[𝔼1,ℂ]<CS𝕝𝕣[𝔼2,ℂ]},Probabilities->Regular]

Suppes & Good

CS𝕤 and CS𝕚𝕛 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕤[𝔼1,ℂ1]≥CS𝕤[𝔼2,ℂ2],CS𝕚𝕛[𝔼1,ℂ1]<CS𝕚𝕛[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕤 and CS𝕚𝕛 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕤[𝔼,ℂ1]≥CS𝕤[𝔼,ℂ2],CS𝕚𝕛[𝔼,ℂ1]<CS𝕚𝕛[𝔼,ℂ2]},Probabilities->Regular]

CS𝕤 and CS𝕚𝕛 are not ordinally equivalent in the class of cases with two effects and a single cause (they are not II–E):

PrSAT[{CS𝕤[𝔼1,ℂ]≥CS𝕤[𝔼2,ℂ],CS𝕚𝕛[𝔼1,ℂ]<CS𝕚𝕛[𝔼2,ℂ]},Probabilities->Regular]

Galton & Cheng

CS𝕘 and CS𝕔 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕘[𝔼1,ℂ1]≥CS𝕘[𝔼2,ℂ2],CS𝕔[𝔼1,ℂ1]<CS𝕔[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕘 and CS𝕔 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕘[𝔼,ℂ1]≥CS𝕘[𝔼,ℂ2],CS𝕔[𝔼,ℂ1]<CS𝕔[𝔼,ℂ2]},Probabilities->Regular]

CS𝕘 and CS𝕔 are not ordinally equivalent in the class of cases with two effects and a single cause (they are not II–E):

PrSAT[{CS𝕘[𝔼1,ℂ]≥CS𝕘[𝔼2,ℂ],CS𝕔[𝔼1,ℂ]<CS𝕔[𝔼2,ℂ]},Probabilities->Regular]

Galton & Lewis Ratio

CS𝕘 and CS𝕝𝕣 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕘[𝔼1,ℂ1]≥CS𝕘[𝔼2,ℂ2],CS𝕝𝕣[𝔼1,ℂ1]<CS𝕝𝕣[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕘 and CS𝕝𝕣 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕘[𝔼,ℂ1]≥CS𝕘[𝔼,ℂ2],CS𝕝𝕣[𝔼,ℂ1]<CS𝕝𝕣[𝔼,ℂ2]},Probabilities->Regular]

CS𝕘 and CS𝕝𝕣 are not ordinally equivalent in the class of cases with two effects and a single cause (they are not II–E):

PrSAT[{CS𝕘[𝔼1,ℂ]≥CS𝕘[𝔼2,ℂ],CS𝕝𝕣[𝔼1,ℂ]<CS𝕝𝕣[𝔼2,ℂ]},Probabilities->Regular]

Galton & Good

CS𝕘 and CS𝕚𝕛 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕘[𝔼1,ℂ1]≥CS𝕘[𝔼2,ℂ2],CS𝕚𝕛[𝔼1,ℂ1]<CS𝕚𝕛[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕘 and CS𝕚𝕛 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕘[𝔼,ℂ1]≥CS𝕘[𝔼,ℂ2],CS𝕚𝕛[𝔼,ℂ1]<CS𝕚𝕛[𝔼,ℂ2]},Probabilities->Regular]

CS𝕘 and CS𝕚𝕛 are not ordinally equivalent in the class of cases with two effects and a single cause (they are not II–E):

PrSAT[{CS𝕘[𝔼1,ℂ]≥CS𝕘[𝔼2,ℂ],CS𝕚𝕛[𝔼1,ℂ]<CS𝕚𝕛[𝔼2,ℂ]},Probabilities->Regular]

Cheng & Lewis Ratio

CS𝕔 and CS𝕝𝕣 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕔[𝔼1,ℂ1]≥CS𝕔[𝔼2,ℂ2],CS𝕝𝕣[𝔼1,ℂ1]<CS𝕝𝕣[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕔 and CS𝕝𝕣 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕔[𝔼,ℂ1]≥CS𝕔[𝔼,ℂ2],CS𝕝𝕣[𝔼,ℂ1]<CS𝕝𝕣[𝔼,ℂ2]},Probabilities->Regular]

CS𝕔 and CS𝕝𝕣 are not ordinally equivalent in the class of cases with two effects and a single cause (they are not II–E):

PrSAT[{CS𝕔[𝔼1,ℂ]≥CS𝕔[𝔼2,ℂ],CS𝕝𝕣[𝔼1,ℂ]<CS𝕝𝕣[𝔼2,ℂ]},Probabilities->Regular]

Cheng & Good

CS𝕔 and CS𝕚𝕛 are ordinally equivalent in general (they are G–E):

PrSAT[{CS𝕔[𝔼1,ℂ1]≥CS𝕔[𝔼2,ℂ2],CS𝕚𝕛[𝔼1,ℂ1]<CS𝕚𝕛[𝔼2,ℂ2]},Probabilities->Regular]

Lewis Ratio & Good

CS𝕝𝕣 and CS𝕚𝕛 are not ordinally equivalent in general (they are not G–E):

PrSAT[{CS𝕝𝕣[𝔼1,ℂ1]≥CS𝕝𝕣[𝔼2,ℂ2],CS𝕚𝕛[𝔼1,ℂ1]<CS𝕚𝕛[𝔼2,ℂ2]},Probabilities->Regular]

CS𝕝𝕣 and CS𝕚𝕛 are not ordinally equivalent in the class of cases with two causes and a single effect (they are not I–E):

PrSAT[{CS𝕝𝕣[𝔼,ℂ1]≥CS𝕝𝕣[𝔼,ℂ2],CS𝕚𝕛[𝔼,ℂ1]<CS𝕚𝕛[𝔼,ℂ2]},Probabilities->Regular]

CS𝕝𝕣 and CS𝕚𝕛 are not ordinally equivalent in the class of cases with two effects and a single cause (they are not II–E):

PrSAT[{CS𝕝𝕣[𝔼1,ℂ]≥CS𝕝𝕣[𝔼2,ℂ],CS𝕚𝕛[𝔼1,ℂ]<CS𝕚𝕛[𝔼2,ℂ]},Probabilities->Regular]

Continuity Property Verification (Table 5)

In this section, we verify the continuity properties of all the measures, as reported in Table 5 of the paper (again, using PrSAT, as above — so if a model is found, then it is a counterexample to the salient continuity property, and if no models are found, then the salient continuity property holds generally in that case).

Causation-Prevention Continuity (CPC)

Eells

PrSAT[{CS𝕖[Y, X]≠-CS𝕖[¬Y , X]}]

Suppes

PrSAT[{CS𝕤[Y, X]≠-CS𝕤[¬Y , X]}]

Galton

PrSAT[{CS𝕘[Y, X]≠-CS𝕘[¬Y , X]}]

Cheng

PrSAT[{CS𝕔[Y, X]≠-CS𝕔[¬Y , X]},Probabilities->Regular]

Lewis Ratio (first rescaling)

PrSAT[{CS𝕝𝕣1[Y, X]≠-CS𝕝𝕣1[¬Y , X]},Probabilities->Regular]

Lewis Ratio (second rescaling)

PrSAT[{CS𝕝𝕣2[Y, X]≠-CS𝕝𝕣2[¬Y , X]},Probabilities->Regular]

Good (first rescaling)

PrSAT[{CS𝕚𝕛1[Y, X]≠-CS𝕚𝕛1[¬Y , X]},Probabilities->Regular]

Good (second rescaling)

PrSAT[{CS𝕚𝕛2[Y, X]≠-CS𝕚𝕛2[¬Y , X]},Probabilities->Regular]

Causation-Omission Continuity (COC)

Eells

PrSAT[{CS𝕖[Y, X]≠-CS𝕖[Y ,¬X]},Probabilities->Regular]

Suppes

PrSAT[{CS𝕤[Y, X]≠-CS𝕤[Y , ¬X]},Probabilities->Regular]

Galton

PrSAT[{CS𝕘[Y, X]≠-CS𝕘[Y , ¬X]}]

Cheng

PrSAT[{CS𝕔[Y, X]≠-CS𝕔[Y , ¬X]},Probabilities->Regular]

Lewis Ratio (first rescaling)

PrSAT[{CS𝕝𝕣1[Y, X]≠-CS𝕝𝕣1[Y , ¬X]}]

Lewis Ratio (second rescaling)

PrSAT[{CS𝕝𝕣2[Y, X]≠-CS𝕝𝕣2[Y ,¬X]},Probabilities->Regular]

Good (first rescaling)

PrSAT[{CS𝕚𝕛1[Y, X]≠-CS𝕚𝕛1[Y , ¬X]}]

Good (second rescaling)

PrSAT[{CS𝕚𝕛2[Y, X]≠-CS𝕚𝕛2[Y , ¬X]},Probabilities->Regular]

Causation = Prevention By Omission Continuity (CPO)

Eells

PrSAT[{CS𝕖[Y, X]≠CS𝕖[¬Y ,¬X]}]

Suppes

PrSAT[{CS𝕤[Y, X]≠CS𝕤[¬Y , ¬X]},Probabilities->Regular]

Galton

PrSAT[{CS𝕘[Y, X]≠CS𝕘[¬Y , ¬X]}]

Cheng

PrSAT[{CS𝕔[Y, X]≠CS𝕔[¬Y , ¬X]},Probabilities->Regular]

Lewis Ratio (first rescaling)

PrSAT[{CS𝕝𝕣1[Y, X]≠CS𝕝𝕣1[¬Y , ¬X]}]

Lewis Ratio (second rescaling)

PrSAT[{CS𝕝𝕣2[Y, X]≠CS𝕝𝕣2[¬Y ,¬X]},Probabilities->Regular]

Good (first rescaling)

PrSAT[{CS𝕚𝕛1[Y, X]≠CS𝕚𝕛1[¬Y , ¬X]}]

Good (second rescaling)

PrSAT[{CS𝕚𝕛2[Y, X]≠CS𝕚𝕛2[¬Y , ¬X]},Probabilities->Regular]

Causal Independence (definitions, and two fundamental properties)

First, we define the various causal independence relations, for the various measures of causal strength:

ICS𝕖[𝔼_,ℂ1_,ℂ2_]:=CS𝕖[𝔼,ℂ1,ℂ2]==CS𝕖[𝔼,ℂ1,¬ℂ2];
ICS𝕤[𝔼_,ℂ1_,ℂ2_]:=CS𝕤[𝔼,ℂ1,ℂ2]==CS𝕤[𝔼,ℂ1,¬ℂ2];
ICS𝕘[𝔼_,ℂ1_,ℂ2_]:=CS𝕘[𝔼,ℂ1,ℂ2]==CS𝕘[𝔼,ℂ1,¬ℂ2];
ICS𝕔[𝔼_,ℂ1_,ℂ2_]:=CS𝕔[𝔼,ℂ1,ℂ2]==CS𝕔[𝔼,ℂ1,¬ℂ2];
ICS𝕝𝕣[𝔼_,ℂ1_,ℂ2_]:=CS𝕝𝕣[𝔼,ℂ1,ℂ2]==CS𝕝𝕣[𝔼,ℂ1,¬ℂ2];
ICS𝕚𝕛[𝔼_,ℂ1_,ℂ2_]:=CS𝕚𝕛[𝔼,ℂ1,ℂ2]==CS𝕚𝕛[𝔼,ℂ1,¬ℂ2];

Then, we set-up our background conditions (BACK), which include the following: (i) that ℂ1 and ℂ2 are unconditionally probabilistically independent, (ii) that ℂ1 and ℂ2 are both positively causally relevant to 𝔼 [i.e., that Pr[𝔼|ℂ1]>Pr[𝔼] and  Pr[𝔼|ℂ2]>Pr[𝔼]].  Finally, to simplify the searches, we will also assume (as part of BACK) — without loss of generality in this context — (iii) that Pr[𝔼|ℂ1]=1/2 and Pr[𝔼]=1/4 and that  Pr[𝔼|ℂ2]=1/2 and Pr[𝔼]=1/4. This last assumption [which is just a more precise way of asserting (ii)] could be relaxed, but the searches would take much longer to complete.

BACK:={Pr[ℂ1|ℂ2]==Pr[ℂ1],Pr[𝔼|ℂ1]>Pr[𝔼],Pr[𝔼|ℂ2]>Pr[𝔼],Pr[𝔼|ℂ1]==1/2,Pr[𝔼]==1/4,Pr[𝔼|ℂ2]==1/2,Pr[𝔼]==1/4};

The following two fundamental properties involving causal Independence judgments are satisfied by all of our measures, given BACK:

•	ICS(𝔼,ℂ1,ℂ2) iff ICS(𝔼,ℂ2,ℂ1) 			[Symmetry of ICS in ℂ1,ℂ2]
•	ICS(𝔼,ℂ1,ℂ2) iff ICS(𝔼,ℂ1,ℂ2)=ICS(𝔼,ℂ1) 	[Equivalence of conditional/unconditional definitions of ICS]

Here are PrSAT-verifications of these fundamental properties (given BACK), for each of our measures of causal strength.  First, we define a non-equivalence relation (≢), to make it easier to assert that a logical equivalence fails to hold:

p_≡q_:=(p\[Implies]q)&&(q\[Implies]p);
p_≢q_:=¬p≡q;

Eells

Symmetry of ICS𝕖 in ℂ1,ℂ2, given BACK:

PrSAT[BACK⋃{ICS𝕖[𝔼,ℂ1,ℂ2]≢ICS𝕖[𝔼,ℂ2,ℂ1]}]

Equivalence of conditional/unconditional definitions of ICS𝕖, given BACK:

PrSAT[BACK⋃{ICS𝕖[𝔼,ℂ1,ℂ2]≢(CS𝕖[𝔼,ℂ1,ℂ2]==CS𝕖[𝔼,ℂ1])}]

Suppes

Symmetry of ICS𝕤 in ℂ1,ℂ2, given BACK:

PrSAT[BACK⋃{ICS𝕤[𝔼,ℂ1,ℂ2]≢ICS𝕤[𝔼,ℂ2,ℂ1]}]

Equivalence of conditional/unconditional definitions of ICS𝕤, given BACK:

PrSAT[BACK⋃{ICS𝕤[𝔼,ℂ1,ℂ2]≢(CS𝕤[𝔼,ℂ1,ℂ2]==CS𝕤[𝔼,ℂ1])}]

Galton

Symmetry of ICS𝕘 in ℂ1,ℂ2, given BACK:

PrSAT[BACK⋃{ICS𝕘[𝔼,ℂ1,ℂ2]≢ICS𝕘[𝔼,ℂ2,ℂ1]}]

Equivalence of conditional/unconditional definitions of ICS𝕘, given BACK:

PrSAT[BACK⋃{ICS𝕘[𝔼,ℂ1,ℂ2]≢(CS𝕘[𝔼,ℂ1,ℂ2]==CS𝕘[𝔼,ℂ1])}]

Cheng

Symmetry of ICS𝕔 in ℂ1,ℂ2, given BACK:

PrSAT[BACK⋃{ICS𝕔[𝔼,ℂ1,ℂ2]≢ICS𝕔[𝔼,ℂ2,ℂ1]}]

Equivalence of conditional/unconditional definitions of ICS𝕘, given BACK:

PrSAT[BACK⋃{ICS𝕔[𝔼,ℂ1,ℂ2]≢(CS𝕔[𝔼,ℂ1,ℂ2]==CS𝕔[𝔼,ℂ1])}]

Lewis Ratio

Symmetry of ICS𝕝𝕣 in ℂ1,ℂ2, given BACK:

PrSAT[BACK⋃{ICS𝕝𝕣[𝔼,ℂ1,ℂ2]≢ICS𝕝𝕣[𝔼,ℂ2,ℂ1]}]

Equivalence of conditional/unconditional definitions of ICS𝕝𝕣, given BACK:

PrSAT[BACK⋃{ICS𝕝𝕣[𝔼,ℂ1,ℂ2]≢(CS𝕝𝕣[𝔼,ℂ1,ℂ2]==CS𝕝𝕣[𝔼,ℂ1])}]

Good

Symmetry of ICS𝕚𝕛 in ℂ1,ℂ2, given BACK:

PrSAT[BACK⋃{ICS𝕚𝕛[𝔼,ℂ1,ℂ2]≢ICS𝕚𝕛[𝔼,ℂ2,ℂ1]}]

Equivalence of conditional/unconditional definitions of ICS𝕚𝕛, given BACK:

PrSAT[BACK⋃{ICS𝕚𝕛[𝔼,ℂ1,ℂ2]≢(CS𝕚𝕛[𝔼,ℂ1,ℂ2]==CS𝕚𝕛[𝔼,ℂ1])}]

Agreement on Causal Independence Judgments (Table 6)

In this section, we verify the claims about agreement on independence judgments reported in Table 6 of the paper (using PrSAT, as above).

Eells & Suppes

CS𝕖 and CS𝕤 agree on all independence judgments (assuming BACK).  First, we show that ICS𝕖[𝔼,ℂ1,ℂ2] => ICS𝕤[𝔼,ℂ1,ℂ2], given BACK:

PrSAT[BACK⋃{ICS𝕖[𝔼,ℂ1,ℂ2],¬ICS𝕤[𝔼,ℂ1,ℂ2]}]

Then, we show that ICS𝕤[𝔼,ℂ1,ℂ2] => ICS𝕖[𝔼,ℂ1,ℂ2], given BACK:

PrSAT[BACK⋃{¬ICS𝕖[𝔼,ℂ1,ℂ2],ICS𝕤[𝔼,ℂ1,ℂ2]}]

Finally, we show that there are some cases (satisfying BACK) in which CS𝕖 and CS𝕤 agree that ℂ1 and ℂ2 are independent causes of 𝔼 (non-triviality):

PrSAT[BACK⋃{ICS𝕖[𝔼,ℂ1,ℂ2],ICS𝕤[𝔼,ℂ1,ℂ2],Pr[ℂ1]==(1/3)},Probabilities->Regular]

Eells & Galton

CS𝕖 and CS𝕘 agree on all independence judgments (assuming BACK).  First, we show that ICS𝕖[𝔼,ℂ1,ℂ2] => ICS𝕘[𝔼,ℂ1,ℂ2], given BACK:

PrSAT[BACK⋃{ICS𝕖[𝔼,ℂ1,ℂ2],¬ICS𝕘[𝔼,ℂ1,ℂ2]}]

Then, we show that ICS𝕘[𝔼,ℂ1,ℂ2] => ICS𝕖[𝔼,ℂ1,ℂ2], given BACK:

PrSAT[BACK⋃{¬ICS𝕖[𝔼,ℂ1,ℂ2],ICS𝕘[𝔼,ℂ1,ℂ2]}]

Finally, we show that there are some cases (satisfying BACK) in which CS𝕖 and CS𝕘 agree that ℂ1 and ℂ2 are independent causes of 𝔼 (non-triviality):

PrSAT[BACK⋃{ICS𝕖[𝔼,ℂ1,ℂ2],ICS𝕘[𝔼,ℂ1,ℂ2],Pr[ℂ1]==(1/3)},Probabilities->Regular]

Eells & Cheng

CS𝕖 and CS𝕔 agree on no independence judgments (assuming BACK).

PrSAT[BACK⋃{ICS𝕖[𝔼,ℂ1,ℂ2],ICS𝕔[𝔼,ℂ1,ℂ2]}]

Eells & Lewis Ratio

CS𝕖 and CS𝕝𝕣 agree on no independence judgments (assuming BACK).

PrSAT[BACK⋃{ICS𝕖[𝔼,ℂ1,ℂ2],ICS𝕝𝕣[𝔼,ℂ1,ℂ2]}]

Eells & Good

CS𝕖 and CS𝕚𝕛 agree on no independence judgments (assuming BACK).

PrSAT[BACK⋃{ICS𝕖[𝔼,ℂ1,ℂ2],ICS𝕚𝕛[𝔼,ℂ1,ℂ2]}]

Suppes & Galton

CS𝕤 and CS𝕘 agree on all independence judgments (assuming BACK).  First, we show that ICS𝕤[𝔼,ℂ1,ℂ2] => ICS𝕘[𝔼,ℂ1,ℂ2], given BACK:

PrSAT[BACK⋃{ICS𝕤[𝔼,ℂ1,ℂ2],¬ICS𝕘[𝔼,ℂ1,ℂ2]}]

Then, we show that ICS𝕘[𝔼,ℂ1,ℂ2] => ICS𝕤[𝔼,ℂ1,ℂ2], given BACK:

PrSAT[BACK⋃{¬ICS𝕤[𝔼,ℂ1,ℂ2],ICS𝕘[𝔼,ℂ1,ℂ2]}]

Finally, we show that there are some cases (satisfying BACK) in which CS𝕤 and CS𝕘 agree that ℂ1 and ℂ2 are independent causes of 𝔼 (non-triviality):

PrSAT[BACK⋃{ICS𝕤[𝔼,ℂ1,ℂ2],ICS𝕘[𝔼,ℂ1,ℂ2],Pr[ℂ1]==(1/3)},Probabilities->Regular]

Suppes & Cheng

CS𝕤 and CS𝕔 agree on no independence judgments (assuming BACK).

PrSAT[BACK⋃{ICS𝕤[𝔼,ℂ1,ℂ2],ICS𝕔[𝔼,ℂ1,ℂ2]}]

Suppes & Lewis Ratio

CS𝕤 and CS𝕝𝕣 agree on no independence judgments (assuming BACK).

PrSAT[BACK⋃{ICS𝕤[𝔼,ℂ1,ℂ2],ICS𝕝𝕣[𝔼,ℂ1,ℂ2]}]

Suppes & Good

CS𝕤 and CS𝕚𝕛 agree on no independence judgments (assuming BACK).

PrSAT[Union[BACK,{ICS𝕤[𝔼,ℂ1,ℂ2],ICS𝕚𝕛[𝔼,ℂ1,ℂ2]}]]

Galton & Cheng

CS𝕘 and CS𝕔 agree on no independence judgments (assuming BACK).

PrSAT[BACK⋃{ICS𝕘[𝔼,ℂ1,ℂ2],ICS𝕔[𝔼,ℂ1,ℂ2]}]

Galton & Lewis Ratio

CS𝕘 and CS𝕝𝕣 agree on no independence judgments (assuming BACK).

PrSAT[BACK⋃{ICS𝕘[𝔼,ℂ1,ℂ2],ICS𝕝𝕣[𝔼,ℂ1,ℂ2]}]

Galton & Good

CS𝕘 and CS𝕚𝕛 agree on no independence judgments (assuming BACK).

PrSAT[BACK⋃{ICS𝕘[𝔼,ℂ1,ℂ2],ICS𝕚𝕛[𝔼,ℂ1,ℂ2]}]

Cheng & Lewis Ratio

CS𝕔 and CS𝕝𝕣 agree on no independence judgments (assuming BACK).

PrSAT[BACK⋃{ICS𝕔[𝔼,ℂ1,ℂ2],ICS𝕝𝕣[𝔼,ℂ1,ℂ2]}]

Cheng & Good

CS𝕔 and CS𝕚𝕛 agree on all independence judgments (assuming BACK).  First, we show that ICS𝕔[𝔼,ℂ1,ℂ2] => ICS𝕚𝕛[𝔼,ℂ1,ℂ2], given BACK:

PrSAT[BACK⋃{ICS𝕔[𝔼,ℂ1,ℂ2],¬ICS𝕚𝕛[𝔼,ℂ1,ℂ2]}]

Then, we show that ICS𝕚𝕛[𝔼,ℂ1,ℂ2] => ICS𝕔[𝔼,ℂ1,ℂ2], given BACK:

PrSAT[BACK⋃{¬ICS𝕔[𝔼,ℂ1,ℂ2],ICS𝕚𝕛[𝔼,ℂ1,ℂ2]}]

Finally, we show that there are some cases (satisfying BACK) in which CS𝕔 and CS𝕚𝕛 agree that ℂ1 and ℂ2 are independent causes of 𝔼 (non-triviality):

PrSAT[BACK⋃{ICS𝕔[𝔼,ℂ1,ℂ2],ICS𝕚𝕛[𝔼,ℂ1,ℂ2],Pr[ℂ1]==(1/3)},Probabilities->Regular]

Lewis Ratio & Good

CS𝕝𝕣 and CS𝕚𝕛 agree on no independence judgments (assuming BACK).

PrSAT[BACK⋃{ICS𝕝𝕣[𝔼,ℂ1,ℂ2],ICS𝕚𝕛[𝔼,ℂ1,ℂ2]}]

Constraint (†) on the values of independent causal strengths

In this section, we will show that some of our measures 𝔪 are such that:

(†) 	ICS𝔪[𝔼, ℂ1, ℂ2] => CS𝔪[𝔼, ℂ1] + CS𝔪[𝔼, ℂ2] ≤ 1.

That is, for some of our measures 𝔪, if ℂ1 and ℂ2 are independent causes of 𝔼 according to 𝔪, then the individual 𝔪-causal-strengths of ℂ1 and ℂ2 cannot sum to more than 1.  We will also show that some measures do not imply any such constraint (†) on independent individual causal strengths.

Eells

CS𝕖 does entail (†):

PrSAT[{ICS𝕖[𝔼,ℂ1,ℂ2],Pr[ℂ1|ℂ2]==Pr[ℂ1],CS𝕖[𝔼,ℂ1]+CS𝕖[𝔼,ℂ2]>1,CS𝕖[𝔼,ℂ1]>0,CS𝕖[𝔼,ℂ2]>0}]

Suppes

CS𝕤 does entail (†):

PrSAT[{ICS𝕤[𝔼,ℂ1,ℂ2],Pr[ℂ1|ℂ2]==Pr[ℂ1],CS𝕤[𝔼,ℂ1]+CS𝕤[𝔼,ℂ2]>1,CS𝕤[𝔼,ℂ1]>0,CS𝕤[𝔼,ℂ2]>0}]

Galton

CS𝕘 does entail (†):

PrSAT[{ICS𝕘[𝔼,ℂ1,ℂ2],Pr[ℂ1|ℂ2]==Pr[ℂ1],CS𝕘[𝔼,ℂ1]+CS𝕘[𝔼,ℂ2]>1,CS𝕘[𝔼,ℂ1]>0,CS𝕘[𝔼,ℂ2]>0}]

Cheng

CS𝕔 does not entail (†):

PrSAT[{ICS𝕔[𝔼,ℂ1,ℂ2],Pr[ℂ1|ℂ2]==Pr[ℂ1],CS𝕔[𝔼,ℂ1]+CS𝕔[𝔼,ℂ2]>1,CS𝕔[𝔼,ℂ1]>0,CS𝕔[𝔼,ℂ2]>0,Pr[ℂ1]==1/2,Pr[ℂ2]==1/2},Probabilities->Regular,BypassSearch->True]

Lewis Ratio (first rescaling)

CS𝕝𝕣1 does not entail (†):

PrSAT[{ICS𝕝𝕣[𝔼,ℂ1,ℂ2],Pr[ℂ1|ℂ2]==Pr[ℂ1],CS𝕝𝕣1[𝔼,ℂ1]+CS𝕝𝕣1[𝔼,ℂ2]>1,CS𝕝𝕣1[𝔼,ℂ1]>0,CS𝕝𝕣1[𝔼,ℂ2]>0,Pr[ℂ1]==1/2,Pr[ℂ2]==1/2},Probabilities->Regular,BypassSearch->True]

Lewis Ratio (second rescaling)

CS𝕝𝕣2 does not entail (†):

PrSAT[{ICS𝕝𝕣[𝔼,ℂ1,ℂ2],Pr[ℂ1|ℂ2]==Pr[ℂ1],CS𝕝𝕣2[𝔼,ℂ1]+CS𝕝𝕣2[𝔼,ℂ2]>1,CS𝕝𝕣2[𝔼,ℂ1]>0,CS𝕝𝕣2[𝔼,ℂ2]>0,Pr[ℂ1]==1/2,Pr[ℂ2]==1/2},Probabilities->Regular,BypassSearch->True]

Good (first rescaling)

CS𝕚𝕛1 does not entail (†):

PrSAT[{ICS𝕚𝕛[𝔼,ℂ1,ℂ2],Pr[ℂ1|ℂ2]==Pr[ℂ1],CS𝕚𝕛1[𝔼,ℂ1]+CS𝕚𝕛1[𝔼,ℂ2]>1,CS𝕚𝕛1[𝔼,ℂ1]>0,CS𝕚𝕛1[𝔼,ℂ2]>0,Pr[ℂ1]==1/2,Pr[ℂ2]==1/2},Probabilities->Regular,BypassSearch->True]

Good (second rescaling)

CS𝕚𝕛2 does not entail (†):

PrSAT[{ICS𝕚𝕛[𝔼,ℂ1,ℂ2],Pr[ℂ1|ℂ2]==Pr[ℂ1],CS𝕚𝕛2[𝔼,ℂ1]+CS𝕚𝕛2[𝔼,ℂ2]>1,CS𝕚𝕛2[𝔼,ℂ1]>0,CS𝕚𝕛2[𝔼,ℂ2]>0,Pr[ℂ1]==1/2,Pr[ℂ2]==1/2},Probabilities->Regular,BypassSearch->True]

Causal Independence and The Causal Strength of Conjunctive Factors

In this section, we show that some of our measures 𝔪 appear to violate the following "independence synergy property":

(S) 	ICS𝔪[𝔼, ℂ1, ℂ2] => (CS𝔪[𝔼, ℂ1 ∧ ℂ2] > CS𝔪[𝔼, ℂ1] & CS𝔪[𝔼, ℂ1 ∧ ℂ2] > CS𝔪[𝔼, ℂ2])

But, that the appearance of the failure of (S) for (all but one of) these measures 𝔪 depends on an incorrect way of calculating "CS𝔪[𝔼, ℂ1 ∧ ℂ2]".  Once this is corrected, we see that — on a proper understanding of "CS𝔪[𝔼, ℂ1 ∧ ℂ2]", all but one of our measures 𝔪 do satisfy (S).  There is but one "recalcitrant" measure — the Galton measure CS𝕘.

Eells

CS𝕖 appears to violate (S), as the existence of the following model indicates:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕖[𝔼,ℂ1,ℂ2]==CS𝕖[𝔼,ℂ1,¬ℂ2],
CS𝕖[𝔼,ℂ1∧ℂ2]<CS𝕖[𝔼,ℂ1]
},
Probabilities->Regular
]

But, on the following proper reformulation of  CS𝕖[𝔼, ℂ1 ∧ ℂ2]

	CS𝕖[𝔼, ℂ1 ∧ ℂ2] = Pr[𝔼 | ℂ1 ∧ ℂ2] - Pr[𝔼 | ¬ℂ1 ∧ ¬ℂ2],

which compares Pr[𝔼 | ℂ1 ∧ ℂ2] and Pr[𝔼 | ¬ℂ1 ∧ ¬ℂ2] rather than Pr[𝔼 | ℂ1 ∧ ℂ2] and Pr[𝔼 | ¬(ℂ1 ∧ ℂ2)], such examples do not exist.  So (S)  is satisfied by CS𝕖 — once it is properly understood.

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕖[𝔼,ℂ1,ℂ2]==CS𝕖[𝔼,ℂ1,¬ℂ2],

Pr[𝔼 |ℂ1∧ℂ2]-Pr[𝔼 | ¬ℂ1∧¬ℂ2]≤CS𝕖[𝔼,ℂ1]
}
]

This is to be expected, in light of the fact that CS𝕖 (assuming a proper reformulation of  CS𝕖[𝔼, ℂ1 ∧ ℂ2]) admits of the following (additive) "decomposition" of the causal strength of a conjunctive causal factor, in cases where it judges the conjuncts to be independent in causing E:

ICS𝕖[𝔼, ℂ1, ℂ2] =>  CS𝕖[𝔼, ℂ1 ∧ ℂ2] = Pr[𝔼 | ℂ1 ∧ ℂ2] - Pr[𝔼 | ¬ℂ1 ∧ ¬ℂ2] = CS𝕖[𝔼, ℂ1] + CS𝕖[𝔼, ℂ1]

This can be verified using PrSAT, as follows:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕖[𝔼,ℂ1,ℂ2]==CS𝕖[𝔼,ℂ1,¬ℂ2],

Pr[𝔼 |ℂ1∧ℂ2]-Pr[𝔼 | ¬ℂ1∧¬ℂ2]≠CS𝕖[𝔼,ℂ1]+CS𝕖[𝔼,ℂ2]
}
]

Suppes

CS𝕤 does not even appear to violate (S):

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕤[𝔼,ℂ1,ℂ2]==CS𝕤[𝔼,ℂ1,¬ℂ2],
CS𝕤[𝔼,ℂ1∧ℂ2]<CS𝕤[𝔼,ℂ1]
},
Probabilities->Regular
]

Thus, CS𝕤 satisfies (S) — even on naive application. This is to be expected, in light of the following (formal) additivity property of CS𝕤:

	ICS𝕤[𝔼, ℂ1, ℂ2] => CS𝕤[𝔼, ℂ1 ∧ ℂ2] = CS𝕤[𝔼, ℂ1] + CS𝕤[𝔼, ℂ2]

which can be verified using PrSAT, as follows:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕤[𝔼,ℂ1,ℂ2]==CS𝕤[𝔼,ℂ1,¬ℂ2],
CS𝕤[𝔼,ℂ1∧ℂ2]≠CS𝕤[𝔼,ℂ1]+CS𝕤[𝔼,ℂ2] 
},
Probabilities->Regular
]

Since the Suppes measure does not involve conditioning on ~C, there is no need to consider reformulations of CS𝕤[𝔼, ℂ1 ∧ ℂ2].

Galton

CS𝕘 appears to violate (S), as the existence of the following model indicates:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕘[𝔼,ℂ1,ℂ2]==CS𝕘[𝔼,ℂ1,¬ℂ2],
CS𝕘[𝔼,ℂ1∧ℂ2]<CS𝕘[𝔼,ℂ1],
Pr[ℂ1]==1/3
},
Probabilities->Regular
]

Surprisingly, even on a proper reformulation of  CS𝕘[𝔼, ℂ1 ∧ ℂ2], which (presumably) would be given by the following:

	CS𝕘[𝔼, ℂ1 ∧ ℂ2] = 4 (Pr[𝔼 ∧ (ℂ1 ∧ ℂ2)] - Pr[𝔼]Pr[ℂ1 ∧ ℂ2])

such examples still exist.  So (S) seems to be violated by CS𝕘 — even once CS𝕘[𝔼, ℂ1 ∧ ℂ2] is properly reformulated.   Here's a "recalcitrant" model:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕘[𝔼,ℂ1,ℂ2]==CS𝕘[𝔼,ℂ1,¬ℂ2],
CS𝕘[𝔼,ℂ1∧ℂ2]<CS𝕘[𝔼,ℂ1],

4 (Pr[𝔼 ∧ (ℂ1 ∧ ℂ2)] - Pr[𝔼]Pr[ℂ1 ∧ ℂ2])<CS𝕘[𝔼,ℂ1],

Pr[ℂ1]==1/4,
Pr[ℂ2]==1/4,
Pr[𝔼]==1/2
},
Probabilities->Regular,
BypassSearch->True
]

Cheng

CS𝕔 appears to violate (S), as the existence of the following model indicates:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕔[𝔼,ℂ1,ℂ2]==CS𝕔[𝔼,ℂ1,¬ℂ2]==1/2,
CS𝕔[𝔼,ℂ1∧ℂ2]<CS𝕔[𝔼,ℂ1]
},
Probabilities->Regular
]

But, on a proper reformulation of  CS𝕔[E, C1 ∧ C2], i.e.:

	CS𝕔[𝔼, ℂ1 ∧ ℂ2] = ((Pr[𝔼 | ℂ1 ∧ ℂ2] - Pr[𝔼 | ¬ℂ1 ∧ ¬ℂ2])/(1 - Pr[𝔼 | ¬ℂ1 ∧ ¬ℂ2]))

which compares Pr[𝔼 | ℂ1 ∧ ℂ2] and Pr[𝔼 | ¬ℂ1 ∧ ¬ℂ2] rather than Pr[𝔼 | ℂ1 ∧ ℂ2] and Pr[𝔼 | ¬(ℂ1 ∧ ℂ2)], such examples do not exist.  So (S) really is satisfied by CS𝕔 — once it is properly understood.

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕔[𝔼,ℂ1,ℂ2]==CS𝕔[𝔼,ℂ1,¬ℂ2],

((Pr[𝔼 |ℂ1∧ℂ2]-Pr[𝔼 | ¬ℂ1∧¬ℂ2])/(1-Pr[𝔼 |¬ℂ1∧¬ℂ2]))≤CS𝕔[𝔼,ℂ1]
}
]

This is to be expected, in light of the fact that CS𝕔 (assuming a proper reformulation of CS𝕔[𝔼, ℂ1 ∧ ℂ2]) admits of the following (multiplicative) "decomposition" of the causal strength of a conjunctive causal factor, in cases where it judges the conjuncts to be independent in causing E:

ICS𝕔[𝔼, ℂ1, ℂ2] => CS𝕔[𝔼, ℂ1 ∧ ℂ2] = ((Pr[𝔼|ℂ1∧ℂ2] - Pr[𝔼|¬ℂ1∧¬ℂ2])/(1 - Pr[𝔼|¬ℂ1∧¬ℂ2])) = 1-(1-CS𝕔[𝔼,ℂ1])(1-CS𝕔[𝔼, ℂ2])

This can be verified using PrSAT, as follows:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕔[𝔼,ℂ1,ℂ2]==CS𝕔[𝔼,ℂ1,¬ℂ2],

((Pr[𝔼 |ℂ1∧ℂ2] - Pr[𝔼 | ¬ℂ1∧¬ℂ2])/(1 - Pr[𝔼|¬ℂ1∧¬ℂ2]))≠ 1 -(1 - CS𝕔[𝔼,ℂ1])(1 - CS𝕔[𝔼, ℂ2])
}
]

Lewis Ratio (non-rescaled)

CS𝕝𝕣 does not even appear to violate (S):

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕝𝕣[𝔼,ℂ1,ℂ2]==CS𝕝𝕣[𝔼,ℂ1,¬ℂ2],
CS𝕝𝕣[𝔼,ℂ1∧ℂ2]≤CS𝕝𝕣[𝔼,ℂ1]
},
Probabilities->Regular
]

Thus, CS𝕝𝕣 satisfies (S) — even on naive application.  This is despite the fact that CS𝕝𝕣[𝔼, ℂ1 ∧ ℂ2] is not properly formulated (on naive application).  What's more important here is that CS𝕝𝕣 satisfies (S), once CS𝕝𝕣[𝔼, ℂ1 ∧ ℂ2] is properly reformulated, as follows:

	CS𝕝𝕣[𝔼, ℂ1 ∧ ℂ2] = ((Pr[𝔼|ℂ1∧ℂ2])/( Pr[𝔼|¬ℂ1∧¬ℂ2]))

This can be verified using PrSAT, as follows:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕝𝕣[𝔼,ℂ1,ℂ2]==CS𝕝𝕣[𝔼,ℂ1,¬ℂ2],
((Pr[𝔼|ℂ1∧ℂ2])/( Pr[𝔼|¬ℂ1∧¬ℂ2]))≤CS𝕝𝕣[𝔼,ℂ1]
},
Probabilities->Regular
]

This is to be expected, in light of the fact that CS𝕝𝕣 (assuming a proper reformulation of CS𝕝𝕣[𝔼, ℂ1 ∧ ℂ2]) admits of the following (multiplicative) "decomposition" of the causal strength of a conjunctive causal factor, in cases where it judges the conjuncts to be independent in causing E:

CS𝕝𝕣[𝔼, ℂ1, ℂ2] => CS𝕝𝕣[𝔼, ℂ1 ∧ ℂ2] = ((Pr[𝔼|ℂ1∧ℂ2])/( Pr[𝔼|¬ℂ1∧¬ℂ2])) = CS𝕝𝕣[𝔼,ℂ1] * CS𝕝𝕣[𝔼, ℂ2]

This can be verified using PrSAT, as follows:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕝𝕣[𝔼,ℂ1,ℂ2]==CS𝕝𝕣[𝔼,ℂ1,¬ℂ2],
((Pr[𝔼|ℂ1∧ℂ2])/( Pr[𝔼|¬ℂ1∧¬ℂ2]))≠CS𝕝𝕣[𝔼,ℂ1]*CS𝕝𝕣[𝔼,ℂ2]
},
Probabilities->Regular
]

Lewis Ratio (second rescaling)

CS𝕝𝕣2 appears to violate (S), as the existence of the following model indicates:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕝𝕣2[𝔼,ℂ1,ℂ2]==CS𝕝𝕣2[𝔼,ℂ1,¬ℂ2],
CS𝕝𝕣2[𝔼,ℂ1∧ℂ2]<CS𝕝𝕣2[𝔼,ℂ1]
},
Probabilities->Regular
]

But, on a proper reformulation of  CS𝕝𝕣2[E, C1 ∧ C2], i.e.:

	CS𝕝𝕣2[𝔼, ℂ1 ∧ ℂ2] = 1 - ((Pr[𝔼 | ¬ℂ1 ∧ ¬ℂ2])/(Pr[𝔼 | ℂ1 ∧ ℂ2]))

which involves Pr[𝔼 | ℂ1 ∧ ℂ2] and Pr[𝔼 | ¬ℂ1 ∧ ¬ℂ2] rather than Pr[𝔼 | ℂ1 ∧ ℂ2] and Pr[𝔼 | ¬(ℂ1 ∧ ℂ2)], such examples do not exist.  So (S) really is satisfied by CS𝕝𝕣2 — once it is properly understood.

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕝𝕣2[𝔼,ℂ1,ℂ2]==CS𝕝𝕣2[𝔼,ℂ1,¬ℂ2],
1 - ((Pr[𝔼 | ¬ℂ1 ∧ ¬ℂ2])/(Pr[𝔼 | ℂ1 ∧ ℂ2]))≤CS𝕝𝕣2[𝔼,ℂ1]
},
Probabilities->Regular
]

This is to be expected, in light of the fact that CS𝕝𝕣2 (assuming a proper reformulation of CS𝕝𝕣2[𝔼, ℂ1 ∧ ℂ2]) admits of the following (multiplicative) "decomposition" of the causal strength of a conjunctive causal factor, in cases where it judges the conjuncts to be independent in causing E:

CS𝕝𝕣2[𝔼, ℂ1, ℂ2] => CS𝕝𝕣2[𝔼, ℂ1 ∧ ℂ2] = 1-((Pr[𝔼 | ¬ℂ1 ∧ ¬ℂ2])/(Pr[𝔼 | ℂ1 ∧ ℂ2])) = 1 - (1-CS𝕝𝕣2[𝔼, ℂ1]) (1 -CS𝕝𝕣2[𝔼, ℂ2])

This can be verified using PrSAT, as follows:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕝𝕣2[𝔼,ℂ1,ℂ2]==CS𝕝𝕣2[𝔼,ℂ1,¬ℂ2],
1-((Pr[𝔼 | ¬ℂ1 ∧ ¬ℂ2])/(Pr[𝔼 | ℂ1 ∧ ℂ2]))≠1 - (1 - CS𝕝𝕣2[𝔼, ℂ1]) (1 - CS𝕝𝕣2[𝔼, ℂ2])
},
Probabilities->Regular
]

Good

CS𝕚𝕛 does not even appear to violate (S):

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕚𝕛[𝔼,ℂ1,ℂ2]==CS𝕚𝕛[𝔼,ℂ1,¬ℂ2]==1/2,
CS𝕚𝕛[𝔼,ℂ1∧ℂ2]<CS𝕚𝕛[𝔼,ℂ1]
},
Probabilities->Regular
]

Thus, CS𝕚𝕛 satisfies (S) — even on naive application.    This is despite the fact that CS𝕚𝕛[𝔼, ℂ1 ∧ ℂ2] is not properly formulated (on naive application).  What's more important here is that CS𝕚𝕛 satisfies (S), once CS𝕚𝕛[𝔼, ℂ1 ∧ ℂ2] is properly reformulated, as follows:

	CS𝕚𝕛[𝔼, ℂ1 ∧ ℂ2] = ((Pr[¬𝔼|¬ℂ1∧¬ℂ2])/( Pr[¬𝔼|ℂ1∧ℂ2]))

This can be verified using PrSAT, as follows:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕚𝕛[𝔼,ℂ1,ℂ2]==CS𝕚𝕛[𝔼,ℂ1,¬ℂ2]==1/2,
((Pr[¬𝔼|¬ℂ1∧¬ℂ2])/( Pr[¬𝔼|ℂ1∧ℂ2]))<CS𝕚𝕛[𝔼,ℂ1]
},
Probabilities->Regular
]

This is to be expected, in light of the fact that CS𝕚𝕛 (assuming a proper reformulation of CS𝕚𝕛[𝔼, ℂ1 ∧ ℂ2]) admits of the following (multiplicative) "decomposition" of the causal strength of a conjunctive causal factor, in cases where it judges the conjuncts to be independent in causing E:

CS𝕚𝕛[𝔼, ℂ1, ℂ2] => CS𝕚𝕛[𝔼, ℂ1 ∧ ℂ2] = ((Pr[¬𝔼|¬ℂ1∧¬ℂ2])/( Pr[¬𝔼|ℂ1∧ℂ2])) = 1-((1-CS𝕚𝕛[𝔼,ℂ1])(1-CS𝕚𝕛[𝔼,ℂ2]))

This can be verified using PrSAT, as follows:

PrSAT[
{
Pr[ℂ1∧ℂ2]==Pr[ℂ1] Pr[ℂ2],
Pr[𝔼|ℂ2]>Pr[𝔼],
Pr[𝔼|ℂ1]>Pr[𝔼],
CS𝕚𝕛[𝔼,ℂ1,ℂ2]==CS𝕚𝕛[𝔼,ℂ1,¬ℂ2]==1/2,
((Pr[¬𝔼|¬ℂ1∧¬ℂ2])/( Pr[¬𝔼|ℂ1∧ℂ2]))≠1 - (1 - CS𝕚𝕛[𝔼,ℂ1])(1 - CS𝕚𝕛[𝔼, ℂ2])
},
Probabilities->Regular
]

Boolean Representations of Cheng, Eells, Suppes, and Lewis Ratio (second rescaling)

Cheng

Assume that (1) 𝔸, ℚ, and ℂ are pairwise independent and jointly independent, and (2) 𝔼 = 𝔸 ∨ (ℚ ∧ ℂ).  Then, we have the following Boolean representation of CS𝕔:

	CS𝕔[𝔼, ℂ] = Pr[ℚ]

Here is a verification:

ASS𝕔={Pr[𝔸∧ℚ]==Pr[𝔸] Pr[ℚ],Pr[𝔸∧ℂ]==Pr[𝔸] Pr[ℂ],Pr[ℚ∧ℂ]==Pr[ℚ] Pr[ℂ],Pr[𝔸∧(ℚ∧ℂ)]==Pr[𝔸] Pr[ℚ∧ℂ]};
𝔼=𝔸∨(ℚ∧ℂ);

PrSAT[ASS𝕔⋃{CS𝕔[𝔼, ℂ]≠Pr[ℚ]}]

Eells

Assume that (1) 𝔸 and ℚ are mutually exclusive, (2) 𝔸 and ℂ are independent, (3) ℚ and ℂ are independent, and (4) 𝔼 = 𝔸 ∨ (ℚ ∧ ℂ).  Then, we have the following Boolean representation of CS𝕖:

	CS𝕖[𝔼, ℂ] = Pr[ℚ]

Here is a verification:

ASS𝕖={Pr[𝔸∧ℚ]==0,Pr[𝔸∧ℂ]==Pr[𝔸] Pr[ℂ],Pr[ℚ∧ℂ]==Pr[ℚ] Pr[ℂ]};

PrSAT[ASS𝕖⋃{CS𝕖[𝔼, ℂ] ≠ Pr[ℚ]}]

Suppes

The same assumptions used for the Eells measure above yield the following Boolean representation of CS𝕤:

	CS𝕤[𝔼, ℂ] = Pr[ℚ ∧ ¬ℂ]

Here is a verification:

PrSAT[ASS𝕖⋃{CS𝕤[𝔼, ℂ] ≠ Pr[ℚ ∧ ¬ℂ]}]

Lewis Ratio (second rescaling)

The same assumptions used for the Eells and Suppes measures above yield the following Boolean representation of CS𝕝𝕣2:
	
	CS𝕝𝕣2[𝔼, ℂ] = Pr[ℚ | ℂ ∧ 𝔼]

Here is a verification:

PrSAT[ASS𝕖⋃{CS𝕝𝕣2[𝔼, ℂ] ≠ Pr[ℚ | ℂ ∧ 𝔼]}]